Я много лет создавал сценарии PowerShell на своем ПК с Windows, но многие должны были запускать вручную. С помощью AutoHotkey (версия 2) я смог воссоздать эти сценарии и связать их с нажатиями клавиш, заставляя их чувствовать встроенные функции Windows Microsoft, забывая упомянуть.
10 Мой личный быстрый приложение запуска приложения
Такие приложения, как блокнот, калькулятор и краска, обычно скрыты от моего рабочего стола, поскольку они не так важны. Но время от времени я обнаружил, что охотиюсь за этими приложениями на их быструю утилиту. Таким образом, вместо того, чтобы просматривать мое меню «Пуск» или значки рабочего стола, я создал пользовательское меню, которое мгновенно появляется, когда я нажимаю клавишу Windows+M, используя скрипт ниже.
#Requires AutoHotkey v2.0
#m::{
MyMenu := Menu()
MyMenu.Add("Calculator", (*) => Run("calc.exe"))
MyMenu.Add("Sticky Notes", (*) => Run("explorer.exe shell:AppsFolder\Microsoft.MicrosoftStickyNotes_8wekyb3d8bbwe!App"))
MyMenu.Add("Notepad", (*) => Run("notepad.exe"))
MyMenu.Add("Paint", (*) => Run("mspaint.exe"))
MyMenu.Show()
}
Я установил свой с калькулятором, малышками, MS Paint и блокнотом. Тем не менее, вы можете легко изменить сценарий, чтобы включить свои собственные фавориты. Хотите добавить понятие? Просто дублируйте одну из существующих строк и измените имя на «понятие», найдите файл .exe для вашего приложения, скопируйте его в качестве пути и вставьте его в рамках скобки.
Мне очень нравится это пользовательское меню. Я просто нажимаю Windows+M, нажимаю на приложение, которое я хочу открыть, и это сделано. Больше не нужно прокручивать списки программ или вспомнить, где я закрепил это приложение, которое мне редко нужно. Я использую это несколько раз в день, и это спасает меня несколько маленьких моментов трения, которые складываются.
9 горизонтальная прокрутка сделана последовательной
Удерживание сдвига+колесо мыши для прокрутки горизонтали не работает со всеми приложениями, которые я использую. К сожалению, я регулярно использую это действие, тем более что я люблю смотреть на фрагменты кода или дизайн в САПР. Итак, я сделал свой собственный сценарий, чтобы сделать горизонтальную прокрутку с любым приложением, которое я использую.
Создайте скрипт со следующим образом, чтобы сделать свою собственную версию:
#Requires AutoHotkey v2.0
#HotIf GetKeyState("Shift", "P")
WheelUp::Send("{WheelLeft}")
WheelDown::Send("{WheelRight}")
#HotIf
Удерживая смену и прокручивая колесо мыши, я могу прокрутить влево и вправо, а не вверх или вниз. Это работает в любой программе, которая поддерживает горизонтальную прокрутку, от электронных таблиц Excel до фото редакторов до веб -браузеров с широким содержанием.
8 Мгновенный доступ к любой папке
Я часто организую свои файлы, используя папки. Тем не менее, иногда я создавал так много подпапок, что доступ к папке проекта принимает у меня несколько кликов мыши для открытия. Затем я понял, что могу легко сделать сценарий, который связывается с Ctrl+Alt+D, чтобы немедленно открыть указанную папку проекта.
Вот сценарий:
#Requires AutoHotkey v2.0
^!d::Run('explorer.exe "C:\Users\jricm\Downloads"')
Вы можете легко изменить этот скрипт, добавив свой путь папки (с кавычками) сразу после «Explorer.exe». Конечно, вы также можете изменить ключевые привязки, используя символы модификатора Auto Hotkey.
Что мне нравится в этом подходе, так это то, насколько он настраивается, когда вы поймете шаблон. Я создал вариации, которые открывают мой рабочий стол, папку моих документов и даже конкретные папки проекта, над которыми я работаю.
7 Быстрая расширения текста для повседневных фраз
Мне нравится идея использования кодов ALT Window, чтобы легко и быстро вставить специальные символы. Я принял тот же подход со сценарием AHK, который позволяет мне использовать ярлыки для общих фраз, которые я часто использую. Создайте этот сценарий, чтобы попробовать самостоятельно:
#Requires AutoHotkey v2.0
#SingleInstance Force
::gm::Good morning
::ty::Thank you
::brb::Be right back
В этом примере всякий раз, когда я набираю «GM», за которым следует пространство (или ввод), он мгновенно расширяется до «Доброе утро». То же самое касается «Тай», который расширяется до «Спасибо» и «BRB» для «Be Back». Это работает в любом приложении, где вы можете печатать, и я считаю его особенно полезным, когда я отвечаю на сообщения в течение дня.
Если вы хотите настроить его, просто добавьте свои собственные сокращения и фразы в том же формате. Это небольшое дополнение, но добавляет немного формальности к моему ежедневному общению и поддерживает мои ответы. Есть и другие способы вставить специальные символы, используя ярлыки Windows, но я считаю, что Autohotkey обеспечивает лучшую настраиваемость.
6 пользовательского регулятора громкости для моей клавиатуры
Управление громкости Windows всегда было неловко для меня. Вы либо нажимаете на этот крошечный значок динамика в системном лотке, либо охотитесь за кнопками громкости на клавиатуре, которые трудно найти, особенно если вы работаете с выключенными огнями, как я. Я хотел что -то более быстрое и интуитивно понятное.
Поскольку мои пальцы всегда приклеены к клавишам домашних рядов, имело смысл связывать регулятор громкости с помощью CTRL + COMMA или CTRL + период для управления громкости, а CTRL + M для мотоцикла и звучания. Это сценарий, который я использовал:
#Requires AutoHotkey v2.0
#SingleInstance Force
^,::Send("{Volume_Down}") ; Ctrl + ^.::Send("{Volume_Up}") ; Ctrl + > (period)
^m::Send("{Volume_Mute}") ; Ctrl + M
Я выбрал эти комбинации, потому что они не конфликтуют с общими ярлыками в большинстве программ, и они всегда находятся в пределах досягаемости пальца. Когда я нахожусь в видеозвонке, и чей -то звук слишком громкий, я могу быстро нажать Ctrl + Comma несколько раз, не прерывая свой рабочий процесс и не исчезаю мышью.
Несмотря на то, что на вашей клавиатуре есть несколько способов настроить пользовательские регуляторы громкости, я предпочитаю использовать Autohotkey. Он имитирует сигналы, которые отправляют выделенные клавиши громкости, обеспечивая совместимость с любым аудиоустройством и всеми настройками звука Windows. У него даже есть наложение громкости, как и если бы вы нажали физические кнопки громкости. Если вы предпочитаете разные комбинации ключей, вы можете легко изменить сценарий. Возможно, Ctrl+Plus и Ctrl+минус чувствуют себя более естественными для вас, или, возможно, вы хотите вместо этого использовать функциональные клавиши.
5 центрирования курсора мыши мгновенно
Это звучит просто, но это удивительно полезно, особенно если вы работаете с мульти-монитором или одной ультравидной установкой. Эта горячая клавиша сосредоточена на вашем курсоре мыши, когда вы нажимаете Ctrl+Alt+c. Первоначально я создал это для игр, но я обнаружил, что использую его в течение дня. Вот сценарий, который вам нужно сделать:
#Requires AutoHotkey v2.0
^!c:: {
WinGetPos(&x, &y, &w, &h, "A")
MouseMove(x + w/2, y + h/2)
}
Сценарий находит точную центральную точку вашего активного окна и мгновенно перемещает мышь. Он работает с любой программой и любым размером окна, даже если окно частично неэкран. Я использую это чаще всего, когда переключается между различными приложениями и хочу быстро сосредоточиться на новом окне, не думая о том, где оказалась моя мышь.
Вы можете изменить этот скрипт, чтобы сосредоточить курсор на весь экран вместо только активного окна, или создать вариации, которые перемещают курсор в определенные позиции, такие как верхний левый угол или правый нижний. Некоторые люди предпочитают, чтобы их курсор автоматически перемещался в кнопку «Закрыть» на Windows, что вы можете выполнить с небольшим изменением позиционирования.
4 папка с автоматической организацией загрузки
-
До
-
После
Моя папка загрузки раньше была хаосом. Скриншоты, смешанные с PDF -файлами, музыкальными файлами рядом со случайными установщиками, все только что сброшено в одну гигантскую кучу. Я пытался оставаться организованным вручную, но у кого есть время для сортировки файлов, когда вы находитесь в середине факта?
Этот скрипт Hotkey работает в фоновом режиме и автоматически сортирует новые загрузки в организованные папки на основе типа файла. Я нажимаю F12, чтобы включить его, и каждые пять секунд он сканирует вашу папку загрузки и перемещает файлы в соответствующие подпапки. PDFS и Word Documents заходят в папку «Docs», изображения переходят в «изображения», музыкальные файлы в «музыку» и так далее. Вот как я его настроил:
#Requires AutoHotkey v2.0
downloads:="C:\Users\jricm\Downloads", interval:=5000
ext:=Map("pdf","Docs","docx","Docs","xlsx","Docs","txt","Text","jpg","Images","png","Images","mp3","Music","mp4","Videos","exe","Programs","zip","Archives")
F12:: {
static on:=false
on:=!on, SetTimer(MoveFiles, on?interval:0)
ToolTip("AutoSort: " (on?"ON":"OFF")), SetTimer(() => ToolTip(), -1500)
}
MoveFiles() {
Loop Files downloads "\*.*", "F"
if ext.Has(e:=A_LoopFileExt) {
d:=downloads "\" ext[e]
if !DirExist(d)
DirCreate(d)
try FileMove(A_LoopFilePath, d "\" A_LoopFileName, 1)
}
}
Сценарий создает эти папки автоматически, если они не существуют, поэтому вам не нужно что -то настраивать заранее. Это достаточно умно, чтобы обрабатывать конфликты файлов. Если вы загружаете два файла с одинаковым именем, он не будет перезаписать существующий.
Если вы также хотите использовать сценарий, который я предоставил, вам сначала придется изменить путь папки рядом с переменной «Загрузки». Вы также можете изменить и добавить другие расширения файлов, добавив тип расширения к переменной «EXT».
Есть небольшая всплеска инструментов, которая появляется, когда вы включаете или выключаете его, но в остальном он просто тихо выполняет свою работу на заднем плане. Пятисекунда интервал означает, что он быстро ловит новые загрузки без постоянного сканирования и замедления вашего компьютера.
3 Запуск нескольких приложений для конкретных рабочих процессов
Я люблю использовать виртуальные рабочие столы Window, чтобы организовать различные задачи. Жаль, что это не позволяет вам открыть определенные приложения или менять приложения на виртуальный рабочий стол. В качестве средства, я использовал Autohotkey, чтобы открыть несколько приложений с одним нажатием клавиши. Вот сценарий, который я использую:
#Requires AutoHotkey v2.0
+1:: {
Run('"C:\Users\jricm\AppData\Local\Programs\Microsoft VS Code\Code.exe"')
Run('"C:\Program Files\JetBrains\DataGrip 2023.3.4\bin\datagrip64.exe"')
Run('"C:\Program Files\Docker\Docker\Docker Desktop.exe"')
}
Нажав Shift+1, сценарий одновременно запускает приложения Visual Studio, DataGrip и Docker. Эти приложения любят не торопиться при загрузке (даже без сценария), так что это прекрасная возможность получить кофе или организовать мое рабочее пространство. К тому времени, когда я готов к работе, все три программы открыты и готовы к работе. Это спасает меня умственные накладные расходы, запоминающую, какие программы мне нужны для определенных проектов, и время, проведенное на переходе, чтобы запустить каждый из них.
Я создал несколько вариантов этого сценария для различных типов работы. Shift+2 запускает мою настройку письма с понятием, Google и Asana. Shift+3 открывает мою трехмерную настройку дизайна, которая включает в себя Fusion 360, Preality Print и Music YouTube. Наличие этих однокварных рабочих пусковых установок устраняет трение начала работы по различным типам проектов.
2 Сохранение важных окон всегда видно
Есть много раз, когда я хочу, чтобы окно оставалось видимым, например, когда я следую учебному пособию, проверяю заметки или общаюсь с людьми. Windows не дает вам простого способа сделать это. Итак, я создал сценарий для этой конкретной цели.
#Requires AutoHotkey v2.0
ScrollLock:: {
try {
activeHwnd := WinGetID("A")
isTopMost := WinGetExStyle(activeHwnd) & 0x8 ; 0x8 = WS_EX_TOPMOST
WinSetAlwaysOnTop(!isTopMost, activeHwnd)
SetScrollLockState(isTopMost ? "Off" : "On")
ToolTip("Always On Top: " (isTopMost ? "OFF" : "ON"))
SetTimer(() => ToolTip(), -1000)
}
}
С помощью сценария выше я могу просто нажать кнопку блокировки прокрутки, пока мое окно активно, и оно остается на вершине всего остального. Сценарий дает мне быстрое выявление инструментов и включает или выключен заблокированный свет прокрутки на моей клавиатуре, поэтому я всегда знаю, что прикреплено. Я использую этот трюк все время, когда мне нужна справочное окно под рукой без необходимости продолжать перемещать вещи или переключаться вперед и назад. Замок прокрутки — хороший выбор, так как большинство людей не используют его для чего -либо еще, но вы можете изменить его на другой ключ, если хотите.
1 предотвращение сна вашего компьютера
Иногда я загружаю и передаю большие файлы на своем компьютере. Весь процесс может занять несколько минут до нескольких часов. Моя проблема заключалась в том, что мои загрузки часто прерываются из -за того, что мой компьютер спал через несколько минут. Это всегда расстраивает меня, когда я пытаюсь повторить или возобновить загрузку, часто терпит неудачу. Чтобы решить проблему, я создал сценарий, который связывается с моими клавишами Ctrl+Alt+Shift+S, чтобы эффективно обходить систему сна моего компьютера.
#Requires AutoHotkey v2.0
#SingleInstance Force
global on := false, endTime := 0
^!+s::{
global on, endTime
if !on {
hrs := InputBox("Enter hours (0 = infinite):", "Anti-Sleep").Value
if !IsNumber(hrs) || hrs return MsgBox("Invalid input.")
endTime := hrs ? A_TickCount + hrs*3600000 : 0
SetTimer(AntiSleep, 300000), SetTimer(CheckEnd, 1000), on := true
ToolTip("Anti-Sleep: ON" (hrs ? "`n" hrs "h" : ""), 500, 500), SetTimer(() => ToolTip(), -1500)
} else { ; Required braces for multi-line else block
SetTimer(AntiSleep, 0), SetTimer(CheckEnd, 0), on := false
ToolTip("Anti-Sleep: OFF", 500, 500), SetTimer(() => ToolTip(), -1000)
}
}
AntiSleep() => (MouseMove(1,0,0,"R"), MouseMove(-1,0,0,"R"))
CheckEnd() => endTime && A_TickCount >= endTime && Send("^!+s")
^!+x::Send("^!+s")
Сценарий работает, перемещая мышь немного каждые пять минут. Таким образом, мой компьютер не идет бездействует и не спит. Я также недавно расширил сценарий, чтобы также включить таймер для деактивации сценария после определенного времени. Сценарий также показывает небольшую всплывающую подсказку, когда вы активируете или деактивируете его, поэтому вы всегда знаете, работает ли он.
Поначалу Autohotkey может показаться пугающей, но вам не нужно понимать каждую строку кода, чтобы извлечь из этого пользу. Загрузите Autohotkey и начните с одного или двух сценариев, которые решают проблемы, которые у вас есть. Как только вы чувствуете себя комфортно с тем, как они работают, постепенно добавляете больше, когда вы обнаружите новые способы улучшить свой рабочий процесс.
